Dict and Dimension

[Arahnid]

Как сделать так , чтобы можно было поставить условие на значение одной из аналитик

static void Arahnid(Args _args)
{

    Dictionary dict = new Dictionary();
    DictTable dictTable;
    DictField dictField;
    int i, k;
    str 300 names;
    extendedTypeId _type;
    common      common;
    Dimension   dim;

    ;
    dim[2] = '0200';
    for (i=1; i<=dict.tableCnt(); i++)
    {
        dictTable = new DictTable(dict.tableCnt2Id(i));
        names = dictTable.name();
        for (k=1; k<=dictTable.fieldCnt(); k++)
        {
            dictField = new DictField(dictTable.id(),dictTable.fieldCnt2Id(k));
            _type = dictField.typeid();
            if (_type == 132)
            {
                common      = dictTable.makeRecord();
                info (names+' Это таблица!');
             //   info(extendedTypeId2name(_type));
                ttsbegin;
                while select forupdate  common
//вот так не работает
                where (common.(dictField.id()) == dim)
                {
                    info(common.(dictField.id()) );
                }
                ttscommit;
            }
        }
    }


}

как выход можно написать так

              common      = dictTable.makeRecord();
             //   info (names+' Это таблица!');
             //   info(extendedTypeId2name(_type));
                ttsbegin;
                while select forupdate  common
               // where (_dim[2] == dim[2])
                {
                    _dim = common.(dictField.id());
                    if (_dim[2] == dim [2])
                    info(_dim[2]  );
                }
                ttscommit;
            }

но я думаю это неправильно

[Russland]

where ( common.(dictField.id()+idx) == dim)
где idx - индекс аналитики

[Russland]

Кстати, что вы там ваяете
Не проще ли

    SalesTable  salesTable;
    ;
    while select salesTable
        where salesTable.Dimension[2] == '00001'
    {
        info(strFmt("%1", salesTable.Dimension[2]));
    }

[Arahnid]

не вышло

ttsbegin;
                while select forupdate  common
                where (common.(dictField.id()+2) == dim[2])
                {
                  /*  _dim = common.(dictField.id());
                    if (_dim[2] == dim [2])*/
                    info(_dim[2]  );
                }
                ttscommit;

[Sada]

Цитата:

Сообщение от Arahnid

не вышло

        where (common.(dictField.id()+2) == dim[2])

Фигня какаято то...Используйте FieldId2Ext для работы с полями типа массив
/*
Returns an extended FieldId, based on the fieldId and the Array index
(an extended FieldId is a fieldId including the array index)
*/
static fieldId fieldId2Ext(fieldId fieldId,
ArrayIdx arrayIndex
)

[Peter Savintsev]

Используйте функцию fieldId2Ext:

                while select forupdate  common
                where (common.(fieldId2Ext(dictField.id()), 2) == dim[2])
                {
                    info(_dim[2]  );
                }
                ttscommit;

И, кстати, никогда не пишите так:

if (_type == 132)

Это противоречит BestPractices и резко сокращает понимаемость кода. Используйте т.н. intrinsic functions, в данном случае extendedTypeNum:

if (_type == extendedTypeNum(Dimension))

[Arahnid]

спасибо

[Sada]

Дело даже и не в том, что индекс явно числом указан. А если его индекс изменится когда нить потом, то что делать? + соглашусь с Петром.

[Peter Savintsev]

Цитата:

Сообщение от Sada

Дело даже и не в том, что индекс явно числом указан. А если его индекс изменится когда нить потом, то что делать?.

Действительно. Более красивый вариант:

int idx = SysDimension::Center + 1;

while select forupdate  common
where (common.(fieldId2Ext(dictField.id(), idx)) == dim[idx])
{
   info(_dim[idx]  );
}

[johny77]

Можно посмотреть вот это
http://blogs.msdn.com/palle_agermark...imensions.aspx

[belugin]

#localmacro.dimNo
   (SysDimension::%1 + 1)
#endmacro

while select forupdate  common
where (common.(fieldId2Ext(dictField.id(), #dimNo(Center))) == dim[#dimNo(Center)])

[Zan]

В Ax40 на таблице Dimensions реализован статический метод code2arrayIdx().
В Ax30 такого стандартного метода нет.

Вместо макроса лучше наверное все-таки использовать то, что уже есть.
Ну, а если таки токого метода нет, то его можно написать.

PHP код:

public static int code2ArrayIdx(SysDimension _sysDimension)
{
    SysDictEnum sysDictEnum;
    ;

    sysDictEnum = new SysDictEnum(enumnum(SysDimension));

    return sysDictEnum.value2Index(_sysDimension) + 1;
} 


[belugin]

Dimensions::code2ArrayIdx(SysDimension::Division)

vs

#dimNo(Division)

[Zan]

Нет, ну я совсем не против.
Это кому как удобнее

[petr]

Цитата:

#dimNo(Division)

А по такой конструкции построятся перекрыстные ссылки (для SysDimension::Division)?

[belugin]

не знаю, наверное, да - вроде перекрестные ссылки юзают ScannerClass - а он автоматически разворачивает макросы

[petr]

Потом попробую - напишу.

Но мне все равно конструкция

#dimNo(Division)

не нравиться.

В конструкции

Dimensions::code2ArrayIdx(SysDimension::Division)

понятнее как-то, что конкретно она делает.

Но у каждого, конечно, свои предпочтения