QueryRun, аналогичный select'у

[Skvorcal]

Коллеги, всем привет.
Столкнулся с маленькой проблемкой, надеюсь получить помощь в ее решении.

Есть исходный запрос X++

    select sum(AmountMST) from ledgerTrans
        where ledgerTrans.AccountNum   == "68.000"
           && ledgerTrans.TransDate    >= 01\01\2010
           && ledgerTrans.TransDate    <= 31\03\2010
        join tableId from ledgerTransOffset
            where ledgerTransOffset.BondBatch_RU        == ledgerTrans.BondBatch_RU
               && ledgerTransOffset.BondBatchTrans_RU   == ledgerTrans.BondBatchTrans_RU
               && ledgerTransOffset.Crediting           != ledgerTrans.Crediting
               && ledgerTransOffset.AccountNum          == "19.320";

Подскажите, плиз, как его реализовать с помощью QueryRun. Трудность вызывает определение связи между двумя таблицами, а конкретнее строчка ledgerTransOffset.Crediting != ledgerTrans.Crediting.

[Gustav]

См. класс RLedgerSheetEngine, метод query.

И еще Связи и Query

[Skvorcal]

Цитата:

Сообщение от Gustav

См. класс RLedgerSheetEngine, метод query.

И еще Связи и Query

Хм, связи "==" реализуются посредством addLink, а все прочие связи - посредством "addRange".

Если я все правильно понял, то получается как-то вот так?

    query   = new Query();
    qbds    = query.addDataSource(tableNum(LedgerTrans));
    qbds.orderMode(OrderMode::GroupBy);

    qbds.addSelectionField(fieldNum(LedgerTrans, AmountMST), SelectionField::Sum);

    qbr = qbds.addRange(fieldNum(LedgerTrans, AccountNum));
    qbr.value("68.000");

    qbr = qbds.addRange(fieldNum(LedgerTrans, TransDate));
    qbr.value(SysQuery::range(01\01\2010, 31\03\2010));

    qbdsOffset = qbds.addDataSource(tableNum(LedgerTrans));
    qbdsOffset.addSelectionField(fieldNum(LedgerTrans, tableId));
    qbdsOffset.joinMode(JoinMode::INNERJOIN);
    qbdsOffset.relations(false);
    qbdsOffset.addLink(fieldnum(LedgerTrans, BondBatch_RU), fieldnum(LedgerTrans, BondBatch_RU));
    qbdsOffset.addLink(fieldnum(LedgerTrans, BondBatchTrans_RU), fieldnum(LedgerTrans, BondBatchTrans_RU));

    qbr = qbdsOffset.addRange(fieldNum(LedgerTrans, Crediting));
    qbr.value('(' + fieldStr(LedgerTrans, Crediting) + '!=' + qbds.name() + '.' + fieldStr(LedgerTrans, Crediting) +')');

    qbr = qbdsOffset.addRange(fieldNum(LedgerTrans, AccountNum));
    qbr.value("19.320");

    queryRun = new QueryRun(query);

[belugin]

http://www.axaptapedia.com/Expressions_in_query_ranges