Получение значений из диалога

[Antant]

Здравствуйте!

Мне нужно получить значение из одного из полей диалога после окончания его работы. Перебором всех полей диалога я нахожу это поле, но значение его всегда равно NULL. Для ясности ситуации привожу джоб.

PHP код:

static void testDialog(Args _args)
{
    Dialog                  cDialog;
    DialogField             _dialogField;

    void showFields(object o,str name)
    {
        formBuildControl    formBuildControl;
        int                 i;
        ;

        for (i=1;i<=o.controlCount(); i++)
        {
            formBuildControl = o.controlNum(i);
            name = cDialog.formBuildDesign().control(formBuildControl.id()).name();
            if (cDialog.formBuildDesign().control(formBuildControl.id()).helpText() == 'tst')
                info( int2str(cDialog.formBuildDesign().control(formBuildControl.id()).value()));

            if (formBuildControl.isContainer())
                showFields(formBuildControl,name);
        }
    }
    ;

    cDialog = new Dialog ('тестовый диалог');

    _dialogField = cDialog.addField(typeId(NoYes), 'тестовое поле диалога');
    _dialogField.helpText('tst');

    cDialog.run();

    showFields(cDialog.formBuildDesign(), 'Test');

    if (!cDialog.closedOk())
        return;

    cDialog.finalize();
} 


Независимо от того, поставить в диалоге галку или нет, он показывает значение 0.

[George Nordic]

Без паники!

Все работает:

static void Job10(Args _args)
{
    Dialog      dialog;
    DialogField dialogFieldName;
    DialogField dialogFieldSex;
    Name        name;
    boolean     isWoman;
    ;
    dialog = new Dialog("Input your name");

    dialogFieldName = dialog.addField(typeId(Name), "Введите Ваше имя");
    //dialogFieldName.helpText('tst');
    dialogFieldSex = dialog.addField(typeId(NoYes), "Вы женщина?");
    //dialogField.helpText('tst');
    if (dialog.run())
    {
        name = dialogFieldName.value();
        isWoman = dialogFieldSex.value();
    }
    else
        throw error("Прервано пользователем");

    info(strfmt("%1, %2",name, isWoman));
}

С Уважением,
Георгий.

ПОЧЕМУ внутренняя переменная начинается с "_" ????
Изучайтк BP. Смотрите tutorials.

[Antant]

В том то и проблема, что я не могу использовать DialogField... я не знаю изначально сколько у меня будет полей. Я создаю поля динамически.

Но спасибо за участие.

Насчет внутренних переменных... если я не ошибаюсь, следуя BP нужно '_' ставить только перед переменными, передаваемыми в функцию... Постараюсь в следующий раз делать правильно, в соотвтетсвии с BP.

[belugin]

Вообще Диалог в трехровневой конфигурации состоит из клиентской и серверной части, и надеятся на то что у него есть контролы нельзя...

[George Nordic]

Цитата:

Сообщение от belugin

Вообще Диалог в трехровневой конфигурации состоит из клиентской и серверной части, и надеятся на то что у него есть контролы нельзя...

Ну, а если передавать dialog как аргумент?

[Antant]

Я уверен, что есть простое решение моей проблемы.
Но пока не осенило.

[Hezl]

Записывайте создаваемые объекты DialogField в массив. Потом ищите нужный в вашем массиве и смотрите его значение

[Antant]

Цитата:

Сообщение от Hezl

Записывайте создаваемые объекты DialogField в массив. Потом ищите нужный в вашем массиве и смотрите его значение

Это как? Можете объяснить подробнее? Как создать массив из DialogField?

[Antant]

Вот что у меня получилось, вариант работающий.

PHP код:

static void testDialog(Args _args)
{
    Dialog                  cDialog;
    DialogField             _dialogField;

    Map                     _map = new Map(Types::String, Types::Class);

    void showFields(object o,str name)
    {
        formBuildControl    formBuildControl;
        int                 i;
        ;

        for (i=1;i<=o.controlCount(); i++)
        {
            formBuildControl = o.controlNum(i);
            name = cDialog.formBuildDesign().control(formBuildControl.id()).name();
            if (cDialog.formBuildDesign().control(formBuildControl.id()).helpText() == 'tst')
            {
                //info( int2str(cDialog.formBuildDesign().control(formBuildControl.id()).value()));
                _dialogField = _map.lookup('tst');
                info (_dialogField.value());
            }

            if (formBuildControl.isContainer())
                showFields(formBuildControl,name);
        }
    }
    ;

    cDialog = new Dialog ('тестовый диалог');

    _dialogField = cDialog.addField(typeId(NoYes), 'тестовое поле диалога');
    _dialogField.helpText('tst');
    _map.insert('tst', _dialogField);

    cDialog.run();

    showFields(cDialog.formBuildDesign(), 'Test');

    if (!cDialog.closedOk())
        return;

    cDialog.finalize();
} 


Спасибо всем, отдельно Hezl.

[Hezl]

Ну как-нибудь так:

static void testDialog(Args _args)
{
    Dialog                  cDialog;
    DialogField             dialogField;
    Array                   arrDialogField = new Array(types::Class);

    void showFields(object o,str name)
    {
        int                 i;
        DialogField         dField;
        ;

        for (i=1;i<=arrDialogField.lastIndex(); i++)
        {
            dField = arrDialogField.value(i);
            info(dField.value());
        }
    }
    ;

    cDialog = new Dialog ('тестовый диалог');

    dialogField = cDialog.addField(typeId(NoYes), 'тестовое поле диалога');
    dialogField.helpText('tst');
    arrDialogField.value(1, dialogField);

    dialogField = cDialog.addField(typeId(Num), 'тестовое поле диалога');
    dialogField.helpText('tst2');
    arrDialogField.value(2, dialogField);

    cDialog.run();

    showFields(cDialog.formBuildDesign(), 'Test');

    if (!cDialog.closedOk())
        return;

    cDialog.finalize();
}

P.S. Или Map

[belugin]

лучше List - он как раз для этого предназначен - для упорядоченных списков или Set если порядок не волнует.