Вопрос по Query с агрегатной функцией

[Jarad]

Пытаюсь написать запрос типа:

select SUM(IT.CostAmountPosted)
from INVENTTRANS IT
inner join InventDim InvDim ON InvDim.InventDimId = IT.InventDimId
where (IT.DateFinancial >= '20060901') AND (IT.DateFinancial <= '20060930')AND (IT.StatusReceipt = 1)

]
Query делал в таком вот виде:

 
qbd = queryExt.addDataSource(tableNum(InventTrans));
qbd.addSelectionField(fieldNum(InventTrans ,CostAmountPosted),SelectionField::Sum) ;
qbd.addRange(fieldNum(InventTrans, DateFinancial)).value(SysQuery::range(bMth,eMth));
qbd.addRange(fieldNum(InventTrans, StatusReceipt)).value(Enum2Str(StatusReceipt::Purchased));
qbd.orderMode(OrderMode::GroupBy);

qbd = queryExt.dataSourceTable(tableNum(InventTrans)).addDataSource(tableNum(InventDim));
   qbd.addLink(fieldNum(InventTrans,InventDimId),fieldNum(InventDim,InventDimId));
   qbd.joinMode(JoinMode::InnerJoin);
   qbd.fetchMode(QueryFetchMode::One2Many);
   qbd.addSortField(fieldNum(InventDim, InventDimId));
   qbd.orderMode(OrderMode::GroupBy);

Но в этом случае группировка будет идти по полю InventDim.InventDimId, и результатом будет не одна общая сумма, а сгрупированые по этому полю. Если же не указать qbd.addSortField, то вобще выскакиевает ошибка... Нужно ли указівать какое то поле в addSortField и каким образом?

[kashperuk]

Честно говоря, не совсем понятно, зачем вы join-ите дополнительно InventDim, если она не учавствует никак в фильтрации или группировке.

Но решить вашу проблему можно очень просто.
Добавить поле выбора на таблицу InventDim:

вместо этого:

    qbd.addLink(fieldNum(InventTrans,InventDimId),fieldNum(InventDim,InventDimId));
    qbd.joinMode(JoinMode::InnerJoin);
    qbd.fetchMode(QueryFetchMode::One2Many);
    qbd.addSortField(fieldNum(InventDim, InventDimId));
    qbd.orderMode(OrderMode::GroupBy);

вставляем вот это:

    qbd.relations(true);
    qbd.addSelectionField(fieldNum(InventDim, InventDimId), SelectionField::Max);

Успехов!

[ALES]

Цитата:

Сообщение от Jarad

Нужно ли указівать какое то поле в addSortField и каким образом?

Есть такое поле tableId..когда список выбора должен быть пуст, помогает))

[Jarad]

Спасибо, помогает.
Просто меня интересовала сама специфика решения такого вопроса, запрос - прсто часть задачи, и на InventDim и фильтры накладываться будут и еще джойниться таблицы.
А с помощью обычного select запрос такого типа реализуется? Что то типа:

select SUM(CostAmountPosted) from invTrans
        join invDim .... 
        where .....

[kashperuk]

Цитата:

Сообщение от Jarad

Спасибо, помогает.
Просто меня интересовала сама специфика решения такого вопроса, запрос - прсто часть задачи, и на InventDim и фильтры накладываться будут и еще джойниться таблицы.
А с помощью обычного select запрос такого типа реализуется? Что то типа:

X++:

select SUM(CostAmountPosted) from invTrans
join invDim ....
where .....

Нет.
Нельзя одновременно выбирать и агрегатные поля и обычные.
Получите точно такую же ошибку:

    InventTrans IT;
    InventDim   InvDim;
    ;
    select SUM(CostAmountPosted)
    from IT
    join InvDim
    where InvDim.InventDimId == IT.InventDimId &&
    IT.DateFinancial >= mkDate(1, 9, 2006) && IT.DateFinancial <= mkDate(30, 9, 2006) &&  IT.StatusReceipt == 1;

[Morpheus]

Цитата:

Сообщение от kashperuk

Нет.
Нельзя одновременно выбирать и агрегатные поля и обычные.

Можно использовать maxof() или minof() для этих целей!

[kashperuk]

Цитата:

Сообщение от Morpheus

Можно использовать maxof() или minof() для этих целей!

См. пост выше.

Цитата:

Сообщение от kashperuk

вставляем вот это:

X++:

qbd.relations(true);
qbd.addSelectionField(fieldNum(InventDim, InventDimId), SelectionField::Max);

Успехов!

[Jarad]

Попробовал реализовать запрос через выражение select

 select Sum(CostAmountPosted) from invTrans
        join maxof(InventDimId) from invDim
        where (invDim.inventDimId == invTrans.inventDimId) &&
        (invTrans.DateFinancial >= bMth) && (invTrans.DateFinancial <= eMth) &&  
        (invTrans.StatusReceipt == StatusReceipt::Purchased);

т.е. если использовать вместо поля выборки в приджойненой таблице тот же maxof(), то получаем тот же самый результат?

[kashperuk]

Именно.
Это же на самом деле одно и то же, что и через QueryBuild*

[AndyD]

Ну, вообще-то, можно еще exists join сделать

    select SUM(CostAmountPosted)
    from IT
    where IT.DateFinancial >= mkDate(1, 9, 2006) && IT.DateFinancial <= mkDate(30, 9, 2006) &&  IT.StatusReceipt == 1
    exists join InvDim
    where InvDim.InventDimId == IT.InventDimId;

только условия выборки разнести

[ALES]

Цитата:

Сообщение от kashperuk

Нет.
Нельзя одновременно выбирать и агрегатные поля и обычные.
Получите точно такую же ошибку:

    InventTrans IT;
    InventDim   InvDim;
    ;
    select SUM(CostAmountPosted)
    from IT
    join InvDim
    where InvDim.InventDimId == IT.InventDimId &&
    IT.DateFinancial >= mkDate(1, 9, 2006) && IT.DateFinancial <= mkDate(30, 9, 2006) &&  IT.StatusReceipt == 1;

Можно только осторожно
Вот так напишите и будет вам счастье

    select SUM(CostAmountPosted)
    from IT
    join tableId from InvDim
    where InvDim.InventDimId == IT.InventDimId...

[Wamr]

Еще можно добавлять группировку по полям, по которым идет фильтрация, например StatusIssue