Параметр [Common table] для RecordSortedList и RecordInsertList

[wojzeh]

Коллеги, кто-нибудь может объяснить назначение необязательного параметра [Common table] для классов RecordSortedList и RecordInsertList?

[dech]

Я подумал, что может быть он сразу копирует данные из этого параметра, если по нему заранее сделать выборку. Но тесты показали, что ничего не происходит.
Еще один странный случай происходит при использовании RecordSortedList. Если не сделать сортировку, вернет только первую запись, а если раскомментировать строку в примере, то все будет ок:

static void testRecordSortedList(Args _args)
{
    SalesTable          salesTable, st;
    RecordSortedList    list = new RecordSortedList(tableNum(SalesTable));
    boolean             more;
    ;

    // list.sortOrder(fieldNum(SalesTable, SalesId));
    
    while select salesTable where
        salesTable.CustAccount  == 'CPG-000002'
    {
        list.ins(salesTable);
    }
    
    for (more = list.first(st); more; more = list.next(st))
    {
        info(st.SalesId);
    }
    info('Done');
}

Бага?

[Maxim Gorbunov]

Цитата:

Сообщение от dech

Бага?

Извините, но RTFM: http://msdn.microsoft.com/en-US/libr...(v=ax.50).aspx
(когда будете читать, учтите, что ключ в RecordSortedList определяется именно с помощью sortOrder)

[Maxim Gorbunov]

Цитата:

Сообщение от wojzeh

Коллеги, кто-нибудь может объяснить назначение необязательного параметра [Common table] для классов RecordSortedList и RecordInsertList?

Параметр какого именно метода этих классов вас интересует?

[dech]

Цитата:

Сообщение от Maxim Gorbunov

Извините, но RTFM: http://msdn.microsoft.com/en-US/libr...(v=ax.50).aspx
(когда будете читать, учтите, что ключ в RecordSortedList определяется именно с помощью sortOrder)

Спасибо, все это я читал, но если не определен ключ, почему вдруг нельзя показать записи в последовательном порядке, в котором они были вставлены в коллекцию?

Цитата:

Сообщение от Maxim Gorbunov

Параметр какого именно метода этих классов вас интересует?

RTFM

[Maxim Gorbunov]

Цитата:

Сообщение от dech

Спасибо, все это я читал, но если не определен ключ, почему вдруг нельзя показать записи в последовательном порядке, в котором они были вставлены в коллекцию?

Потому что в RecordSortedList не может быть дубликатов записей. Почитайте повнимательнее про метод ins() . Две записи считаются одинаковыми, если у них совпадают значения ключевых полей. Если ключевых полей нет, то любые две записи автоматически будут считаться одинаковыми.

Цитата:

Сообщение от dech

RTFM

Для тех, кто как и я (если такие есть), не понял сразу, о чём спрашивает автор темы, поясню. Вопрос про AX2012, метод new() классов RecordSortedList и RecordInsertList. Я ответа на него не знаю. Возможно, кто-то из присутствующих на форуме представителей Microsoft сможет помочь.

А вообще, Как правильно задать вопрос, чтобы быть услышанным

[S.Kuskov]

Может быть туда можно курсор временной таблицы передать? Допустим не InMemory, а TempDB, было бы вполне логично.

[Maxim Gorbunov]

Цитата:

Сообщение от S.Kuskov

Может быть туда можно курсор временной таблицы передать? Допустим не InMemory, а TempDB, было бы вполне логично.

Да, судя по всему, вы правы. Пример можно посмотреть в классе LedgerBalanceSheetDimPrint, метод generateKnownCombinations().

[belugin]

В исходниках переменная называется pTempDBCursor

[wojzeh]

Цитата:

Сообщение от Maxim Gorbunov

Да, судя по всему, вы правы. Пример можно посмотреть в классе LedgerBalanceSheetDimPrint, метод generateKnownCombinations().

Да, Макс, ты прав, речь идёт о методе new -- пропустил ключевое слово, когда писал!

Теперь о самом параметре в контексте самого класса RecordInsertList. Вот данный кусок, где, видимо, данные будут вставлены во временный буфер.

        recordInsertList = new RecordInsertList(tableNum(LedgerBalanceSheetUsedDimensionsTmp), false, false, false, false, false, _usedTmp);

        queryRun = new QueryRun(query);

        while (queryRun.next())
        {
            _usedTmp.clear();

            for (i = 1; i <= usedDimensions.lastIndex(); i++)
            {
                dimensionAttributeLevelValueAllView = queryRun.get(tableNum(DimensionAttributeLevelValueAllView), i);
                _usedTmp.EntityValue[i] = dimensionAttributeLevelValueAllView.DisplayValue;
                _usedTmp.EntityInstance[i] = dimensionAttributeLevelValueAllView.EntityInstance;
            }

            recordInsertList.add(_usedTmp);
        }

        recordInsertList.insertDatabase();

Теперь вопрос следующий: в чём смысл (профит) использования этого класса с временной таблицей, если в документации сказано:

The array insert operation automatically falls back to classic record-by-record inserts when non-SQL based tables are used (for example, temporary tables)...

Теперь сравним, как работают эти братские классы при передаче им в качестве параметра временной таблицы (InMemory).

RecordInsertList

private void runRIL() //RIL, temporary buffer contains two records
{
    uapTestTable        t;
    uapTestTable        t2;
    RecordInsertList    ril;

    t.setTmp();
    ril = new RecordInsertList(t.TableId, true, true, true, false, false, t);

    ttsBegin;

    t.code = "001";
    t.value = 1;
    ril.add(t);
    
    t.code = "002";
    t.value = 10;
    ril.add(t);

    ril.insertDatabase();
    ttsCommit;
    
    info('temporary uapTestTable');
    while select t
    {
        info(strFmt("%1 %2", t.code, t.value));
    }
    info('normal uapTestTable');
    while select t2
    {
        info(strFmt("%1 %2", t2.code, t2.value));
    }
/*    
Info	Message (01:40:51 pm)	temporary uapTestTable
Info	Message (01:40:51 pm)	001 1
Info	Message (01:40:51 pm)	002 10
Info	Message (01:40:51 pm)	normal uapTestTable
*/
}

RecordSortedList

private void runRSL()
{
    uapTestTable        t;
    uapTestTable        t2;
    RecordSortedList    rsl;

    t.setTmp();
    rsl = new RecordSortedList(t.TableId, t);
    rsl.sortOrder(fieldNum(uapTestTable, Code));

    ttsBegin;

    t.code = "001";
    t.value = 1;
    rsl.ins(t);

    t.code = "002";
    t.value = 10;
    rsl.ins(t);
    
    rsl.insertDatabase();
    ttsCommit;
    
    info('RecordSortedList temporary buffer contains no records, but two inserted in uapTestTable table');
    info('temporary uapTestTable');
    while select t
    {
        info(strFmt("%1 %2", t.code, t.value));
    }
    info('normal uapTestTable');
    while select t2
    {
        info(strFmt("%1 %2", t2.code, t2.value));
    }
    
/*
Info	Message (01:42:07 pm)	RecordSortedList temporary buffer contains no records, but two inserted in uapTestTable table
Info	Message (01:42:07 pm)	temporary uapTestTable
Info	Message (01:42:07 pm)	normal uapTestTable
Info	Message (01:42:07 pm)	001 1
Info	Message (01:42:07 pm)	002 10
*/
   
}

Выходит, что внутри у них что-то по-разному устроено, и под temporary table подразумевается именно InMemory, но не TempDB.

Какие будут соображения?

[Maxim Gorbunov]

Цитата:

Сообщение от wojzeh

Выходит... под temporary table подразумевается именно InMemory, но не TempDB.

wojzeh, честно говоря, совсем не понял, почему ты делаешь такой вывод. Пояснишь?

Как мне кажется, нет смысла использовать RecordSortedList/RecordInsertList для временных таблиц InMemory, потому что в некотором смысле это альтернативные механизмы, а не взаимодополняющие.

Цитата:

Сообщение от wojzeh

Теперь вопрос следующий: в чём смысл (профит) использования этого класса с временной таблицей, если в документации сказано:

The array insert operation automatically falls back to classic record-by-record inserts when non-SQL based tables are used (for example, temporary tables)...

Ну да, в документации сказано про non-SQL based tables, а временная таблица TempDB - она очень даже SQL based Соответственно, профит тот же самый, что и при использовании этих классов с обычными таблицами: вставляемые записи собираются в пакеты большего размера и за счёт этого происходит меньше вызовов клиент/сервер.

[wojzeh]

Цитата:

Сообщение от Maxim Gorbunov

wojzeh, честно говоря, совсем не понял, почему ты делаешь такой вывод. Пояснишь?

Как мне кажется, нет смысла использовать RecordSortedList/RecordInsertList для временных таблиц InMemory, потому что в некотором смысле это альтернативные механизмы, а не взаимодополняющие.

Ну да, в документации сказано про non-SQL based tables, а временная таблица TempDB - она очень даже SQL based Соответственно, профит тот же самый, что и при использовании этих классов с обычными таблицами: вставляемые записи собираются в пакеты большего размера и за счёт этого происходит меньше вызовов клиент/сервер.

ну, так вот я теперь и понял, что временная, но всё же сикель-базированная! именно её имеет смысл передавать в качестве параметра для ускорения.

при этом можно так же лихо подсунуть ей и настоящую "времянку", но только не в случае с RecordSortedList.

в любом случае это пробел в документации, и неплохо было бы его восполнить.

у меня как раз тут задача о быстрой вставке сотен тысяч записей, но именно во временную таблицу для последующих расчётов.

[Logger]

А кто-нибудь юзал RecordInsertList совместно с UserConnection ?

[Logger]

Вот гадство.
При выполнении на клиенте кода аналогичного этому

recordInsertList = new RecordInsertList(tableNum(LedgerBalanceSheetUsedDimensionsTmp), false, false, false, false, false, _usedTmp);

не работает, но выдает ошибочное сообщение об ошибке

Цитата:

Операции RecordInsertList или RecordSortedList с временными таблицами базы данных не разрешены.
Объект "RecordInsertList" не может быть создан

из сообщения можно ошибочно подумать что с времянками в tempdb в принципе не работает.
А оно работает, но нужно объект на сервере создавать.