Вопрос по Query

[tischenko]

Подскажите пожалуйста как на языке Query реализовать такую вещь: есть некая форма в которой в датасоурсах LedgerTrans, который собственно и нужно отфильтровать таким образом, что бы в нем отображались только те проводки у которых Voucher =(любому) VendTrans.Voucher. Вобщем нужно чтобы в LedgerTrans отобразились только те записи, документ ГК у которых присутствует в проводках по поставщиках.

[Maxim Gorbunov]

PHP код:

Query query;
QueryBuildDataSource qbds;
;
query = new Query();
qbds = query.addDataSource(tableNum(LedgerTrans));
qbds.addDataSource(tableNum(VendTrans));
qbds.addLink(fieldNum(LedgerTrans, Voucher), fieldNum(VendTrans, Voucher));
qbds.joinMode(JoinMode::ExistsJoin); 


[tischenko]

Спасибо. Это получилось.

А как сделать если есть

query1 = new Query();
qbds1 = query1.addDataSource(tableNum(LedgerTrans));

query2 = new Query();
qbds2 = query2.addDataSource(tableNum(VendTrans));
qbds2.addRange(чегото там);

И как отфильтровать или сделать линк Query1 только по тем Voucher-ам которые есть в Query2?

[Maxim Gorbunov]

Это два разных запроса получится.

А вам нужен один.

[tischenko]

QueryRun LedgerTransQueryRun;
QueryRun VendTransQueryRun;

Query LedgerTransQuery;
Query VendTransQuery;

QueryBuildDataSource LedgerTransQBDS;
QueryBuildDataSource VendTransQBDS;

LedgerTrans ledgerTrans;
VendTrans vendTrans;
;

VendTransQuery = new Query();
VendTransQBDS = VendTransQuery.addDataSource(TableNum(VendTrans));
VendTransQBDS.addRange(FieldNum(VendTrans,AccountNum)).value('Ivanov');
VendTransQueryRun = new QueryRun(VendTransQuery);

LedgerTransQuery = new Query();
LedgerTransQBDS = LedgerTransQuery.addDataSource(TableNum(LedgerTrans));
ledgerTransQBDS.addRange(fieldnum(LedgerTrans,Crediting)).value(SysQuery::value(NoYes::No));

LedgerTransQueryRun = new QueryRun(LedgerTransQuery);
while (LedgerTransQueryRun.next())
{
ledgerTrans = LedgerTransQueryRun.get(TableNum(LedgerTrans));
info(ledgerTrans.AccountNum);
//
}

И вобщем нужно отфильтровать LedgerTransQuery согласно отфильтрованному VendTransQuery. Как можно такое реализовать?

[macklakov]

tischenko, Maxim Gorbunov вам уже все правильно сказал. Еще раз вчитайтесь в свой код, попытайтесь понять зачем используется тот или иной класс

[tischenko]

Сам запутался. Но разобрался.
Спасибо за ответы.
Вот что мне нужно было:

PHP код:

QueryRun LedgerTransQueryRun;
Query LedgerTransQuery;
QueryBuildDataSource LedgerTransQBDS;
QueryBuildDataSource VendTransQBDS;
LedgerTrans ledgerTrans;
;
LedgerTransQuery = new Query();
VendTransQBDS = LedgerTransQuery.addDataSource(TableNum(VendTrans));
VendTransQBDS.addRange(FieldNum(VendTrans,AccountNum)).value('Ivanov LTD');
LedgerTransQBDS = VendTransQBDS.addDataSource(tableNum(LedgerTrans));
LedgerTransQBDS.addLink(fieldNum(VendTrans, Voucher),fieldNum(LedgerTrans, Voucher));
ledgerTransQBDS.addRange(fieldnum(LedgerTrans,Crediting)).value(SysQuery::value(NoYes::No));
LedgerTransQueryRun = new QueryRun(LedgerTransQuery);
while (LedgerTransQueryRun.next())
{
    ledgerTrans = LedgerTransQueryRun.get(TableNum(LedgerTrans));
    info(ledgerTrans.AccountNum);
}