записать файл в UTF-кодировке

[Atani]

Здравствуйте!

Требуется из Аксапты создавать текстовый файл в кодировке UTF-8 (Обычный asciiio создаёт файл в windows-1251). Как такое сотворить?

Возможно, кто-нибудь знает способ перекодироки "на лету" или внешнюю утилиту перекодировки, которую можно было бы запустить программно сразу после создания файла

[EVGL]

Можно по такой схеме: Axapta -> XML -> XSLT -> CSV

[Atani]

Это мой запасной вариант :-)

Только почему нельзя пропустить фазу XSLT?
Разве не достаточно будет XMLDocument.save(filename); ?

[EVGL]

Можно. Если вы создаете XML.

[AndyD]

Рискну предложить свой вариант на основе виндовых функций

[Atani]

Спасибо!

[Logger]

Цитата:

Сообщение от AndyD

Рискну предложить свой вариант на основе виндовых функций

спасибо за код.

странно в 2009-й функция Utf2Ansi() валится с ошибкой "Метод вызван с недопустимыми параметрами" на вызове

buf.string(0, _utf8);

[someOne]

Цитата:

странно в 2009-й функция Utf2Ansi() валится с ошибкой "Метод вызван с недопустимыми параметрами" на вызове

X++:
buf.string(0, _utf8);

Может быть поэтому ? Ошибка при работе с binary в Ax2009

[someOne]

Еще - в Ax2009, наверное, лучше делать так (через NET):

static void Job31(Args _args)
{
    System.IO.StreamWriter file;
    ;
    file = new System.IO.StreamWriter("C:\\Test.txt", true, System.Text.Encoding::get_UTF8());
    file.WriteLine("Привет из Axapta");
    file.Close();
}

Гарантировано не будет проблем, например, при запуске на стороне сервера.
Замечал, что не все низкоуровневые api функции работают на стороне сервера.
Может проблема в том что операционная система сервера 64 bit ?
Наверное поэтому все серверные вызовы api (класс WinApiServer) переделаны на NET в axapta 2009.

[AndyD]

Угу, насчет .NET согласен.
Вот так можно без промежуточных файлов работать с UTF8

{
    System.Text.UTF8Encoding    UTF8Encoding;
    System.Byte[]               bytes;
    System.Byte[]               utf8;
    int i;
    int len;
    int val;
    Binary  bin;
    ;
    UTF8Encoding = new System.Text.UTF8Encoding();
    bytes = UTF8Encoding.GetBytes("Строка UTF8");
    len = bytes.get_Length();
    bin = new Binary(len);
    for (i=0;i<len;i++)
    {
        val = bytes.GetValue(i);
        bin.byte(i, val);
    }
    info(bin.string(0));
    
    utf8 = new System.Byte[len]();
    for (i=0;i<len;i++)
        utf8.SetValue(System.Convert::ToByte(bin.byte(i)), i);

    info(UTF8Encoding.GetString(utf8));
}

По сути вопроса - возможно, проблемы из-за того, что строки теперь юникодные и преобразование на каком-то этапе идет неправильно.

[DSPIC]

Ещё простой вариант:

    TextBuffer      textBuffer;
    ;
    
    textBuffer = new TextBuffer();
    textBuffer.setText("Строка");
    textBuffer.toFile(@"C:\utf8.txt", FileEncoding::UTF8);

[GBH]

Цитата:

Сообщение от someOne

Еще - в Ax2009, наверное, лучше делать так (через NET):

static void Job31(Args _args)
{
    System.IO.StreamWriter file;
    ;
    file = new System.IO.StreamWriter("C:\\Test.txt", true, System.Text.Encoding::get_UTF8());
    file.WriteLine("Привет из Axapta");
    file.Close();
}

Гарантировано не будет проблем, например, при запуске на стороне сервера.
Замечал, что не все низкоуровневые api функции работают на стороне сервера.
Может проблема в том что операционная система сервера 64 bit ?
Наверное поэтому все серверные вызовы api (класс WinApiServer) переделаны на NET в axapta 2009.

А как добиться работы данного кода на сервере?
У меня ругается на InteropPermission.
Пытался применить,то что написано здесь, но не помогает.
http://msdn.microsoft.com/en-us/library/bb190039.aspx
Видимо руки кривые.

static client работает корректно, но хотелось бы на сервере добиться работы.
Заранее спасибо.

[pedrozzz]

Цитата:

Сообщение от GBH

А как добиться работы данного кода на сервере?

Быть может так получится:

static void Job31(Args _args)
{
    FileName                fileName      = @'C:\Test.txt';
    Set                     permissionSet = new set(Types::Class);
    System.Text.Encoding    encoding;
    System.IO.StreamWriter  file;
    #File
    ;

    permissionSet.add(new FileIOPermission(fileName, #io_write));
    permissionSet.add(new InteropPermission(InteropKind::ClrInterop));

    CodeAccessPermission::assertMultiple(permissionSet);

    try
    {
        encoding = System.Text.Encoding::get_UTF8();
        file     = new System.IO.StreamWriter(fileName, true, encoding);

        file.WriteLine("Привет из Axapta на сервере");

        file.Close();
    }
    catch
    {
        error(AifUtil::getClrErrorMessage());
    }

    CodeAccessPermission::revertAssert();
}

[jonny]

Класс TextIo позволяет задавать кодировку, используется так же как AsciiIo
http://msdn.microsoft.com/en-us/libr...=ax.50%29.aspx

[GBH]

Цитата:

Сообщение от pedrozzz

Быть может так получится:

static void Job31(Args _args)
{
    FileName                fileName      = @'C:\Test.txt';
    Set                     permissionSet = new set(Types::Class);
    System.Text.Encoding    encoding;
    System.IO.StreamWriter  file;
    #File
    ;

    permissionSet.add(new FileIOPermission(fileName, #io_write));
    permissionSet.add(new InteropPermission(InteropKind::ClrInterop));

    CodeAccessPermission::assertMultiple(permissionSet);

    try
    {
        encoding = System.Text.Encoding::get_UTF8();
        file     = new System.IO.StreamWriter(fileName, true, encoding);

        file.WriteLine("Привет из Axapta на сервере");

        file.Close();
    }
    catch
    {
        error(AifUtil::getClrErrorMessage());
    }

    CodeAccessPermission::revertAssert();
}

Спасибо за ответ!
К сожалению, всё также как и у меня.

 (08:35:07)
 "CLRObject"    
      "C:\Test.txt".

[GBH]

Цитата:

Сообщение от jonny

Класс TextIo позволяет задавать кодировку, используется так же как AsciiIo
http://msdn.microsoft.com/en-us/libr...=ax.50%29.aspx

Спасибо за информацию!
Но мне хочется разобраться именно с вариантом NET.

[pedrozzz]

У меня работает. Проверьте, есть ли у AOS доступ к каталогу.

[mayk]

Цитата:

Сообщение от pedrozzz

У меня работает. Проверьте, есть ли у AOS доступ к каталогу.

Windows с включенным UAC очень не любит когда в корень пишут файлы.
К примеру в 7-ке не получится просто так создать файл в корне даже из под учетки с админскими правами. Получится только если запускать приложения по правому клику "запускать от имени администратора"

[someOne]

Цитата:

Сообщение от GBH

А как добиться работы данного кода на сервере?
У меня ругается на InteropPermission.

Для избежания этой ошибки в начале метода достаточно вставить

new InteropPermission(InteropKind::ClrInterop).assert();

Обсуждалось неоднократно...

[plumbum]

Я бы все таки сделал так:

    FileName    fileName;
    str         fileContent;
    ;
    
    new InteropPermission(InteropKind::ClrInterop).assert();
    
    System.IO.File::WriteAllText(fileName, fileContent, System.Text.Encoding::get_UTF8());
    
    CodeAccessPermission::revertAssert();

таким образом не надо освобождать файл методом Close() и нигде не хранятся ссылки на .NET объекты, которые потом АОС должен освобождать.

Удачи