Акс 3.0 Запросы на источнике с или

[Arahnid]

Создан EDT FilmCode по примеру Dimension, но состоит из 25 элементов. Тип данных в нем int.

Затем сделана форма и одна из группы полей на grid FilmCode.

Задача отфильтровать те строки, где в группе FilmCode хотя бы в одном элементе указано выбранное значение. Значение указывается через специальное поле StringEdit на форме.

Пишу запрос

public void executeQuery()
{
    QueryBuildRange      qbdsrange1;
    QueryBuildDataSource qbds1;
    Integer              _idx;
    str 10000      strFilter;
    str 10 CinemaFilmCode;
    ;
    qbds1 = this.query().dataSourceTable(tableNum(CinemaSchTable));
    CinemaFilmCode = int2str(CinemaFilmTable::findName(FindFilm.valueStr()).FilmCode);
    qbds1.clearRange(fieldId2Ext(fieldNum(CinemaSchTable,FilmCode),1));

    if (FindFilm.valueStr())
    {
        qbdsrange1 =  qbds1.addRange(fieldNum(CinemaSchTable,FilmCode));
        strFilter = '((CinemaSchTable.FilmCode[1] == '+CinemaFilmCode+')';
        for (_idx=2; _idx <=25; _idx++)
        {
               strFilter +=  ' || (CinemaSchTable.FilmCode['+ int2str(_idx)+'] == '+ CinemaFilmCode+')';
        }       
        strFilter += ')';
        qbdsrange1.value(strFmt(strFilter));
    }
    super();
}

Выдает ошибку нехватает скобки правой на 28 символе. Однако, этот же запрос через обзор таблицы работает.
SELECT * FROM CinemaSchTable WHERE ((((CinemaSchTable.FilmCode[1] == 437) || (CinemaSchTable.FilmCode[2] == 437) || (CinemaSchTable.FilmCode[3] == 437) || (CinemaSchTable.FilmCode[4] == 437) || (CinemaSchTable.FilmCode[5] == 437) || (CinemaSchTable.FilmCode[6] == 437) || (CinemaSchTable.FilmCode[7] == 437) || (CinemaSchTable.FilmCode[8] == 437) || (CinemaSchTable.FilmCode[9] == 437) || (CinemaSchTable.FilmCode[10] == 437) || (CinemaSchTable.FilmCode[11] == 437) || (CinemaSchTable.FilmCode[12] == 437) || (CinemaSchTable.FilmCode[13] == 437) || (CinemaSchTable.FilmCode[14] == 437) || (CinemaSchTable.FilmCode[15] == 437) || (CinemaSchTable.FilmCode[16] == 437) || (CinemaSchTable.FilmCode[17] == 437) || (CinemaSchTable.FilmCode[18] == 437) || (CinemaSchTable.FilmCode[19] == 437) || (CinemaSchTable.FilmCode[20] == 437) || (CinemaSchTable.FilmCode[21] == 437) || (CinemaSchTable.FilmCode[22] == 437) || (CinemaSchTable.FilmCode[23] == 437))))

Если писать без указания таблицы FilmCode[24] = 541..., то тоже не работает.
Если писать = или вместо || поставить or, то тоже не работает.
Если в qbdsrange1.value(strFmt(strFilter)); записать просто 541, то по первому полю в группе работает.
Не могу понять где ошиблась.

Если

    if (FindFilm.valueStr())
    {
        qbdsrange1 =  qbds1.addRange(fieldid2ext(fieldNum(CinemaSchTable,FilmCode),1));
        strFilter = ' == 1)||(CinemaSchTable.FilmCode[1] == '+CinemaFilmCode+')';
        for (_idx=2; _idx <=2; _idx++)
        {
               strFilter +=  ' || (CinemaSchTable.FilmCode['+ int2str(_idx)+'] == '+ CinemaFilmCode+')';
        }       
        strFilter += '';
        qbdsrange1.value(strFmt(strFilter));
    }

ошибок нет, но и фильтр не работает
Такое впечатление, что он пытается зачем-то поставить FilmCode[1] =

[miklenew]

У вас длина не умещается в отведённые типом Range 250 символов.
Или скоко там у вас стоит.
Если бы этот query использовался токо в коде проблем бы не было.
Но он у вас идёт на форму, а там есть такое ограничение.

[lev]

попробуйте вот так:

if (FindFilm.valueStr())
    {
        for (_idx=2; _idx <=25; _idx++)
        {
               qbdsrange1 = qbds1.addRange(fieldId2Ext(fieldNum(CinemaSchTable,FilmCode),_idx));
               qbdsrange1.value(QueryValue(CinemaFilmCode));
        }
        
    }

[miklenew]

И ещё интересно как система будет работать с 25 полями.
25 не перебор ли?

[lev]

все дело в том что вот здесь:

qbdsrange1 =  qbds1.addRange(fieldid2ext(fieldNum(CinemaSchTable,FilmCode), 1));

вы создаете range только для первого элемента в массиве, и в его условие пытаетесь добавить сфорированный вами запрос по всем элементам. вот он вас и не понимает

[lev]

а, ещё нюанс
в БД (Oracle, SQL) массивные поля храняться в виде нескольких полей в виде Dimension, Dimension2_, Dimension3_ ... Dimension25_
а вы в запрос вставляете Dimension[25] база не знает такого поля

[lev]

сорри...
погорячился, вижу что вам нужно ИЛИ, а в моем варианте подставляется И.
насчет хранения полей-массивов я написал правильно, НО аксапта отправляет запрос в виде Dimension[25]...

сейчас попробую сделать ИЛИ

[Arahnid]

Цитата:

Сообщение от lev

попробуйте вот так:

if (FindFilm.valueStr())
    {
        for (_idx=2; _idx <=25; _idx++)
        {
               qbdsrange1 = qbds1.addRange(fieldId2Ext(fieldNum(CinemaSchTable,FilmCode),_idx));
               qbdsrange1.value(QueryValue(CinemaFilmCode));
        }
        
    }

Запрос работает через And. А мне нужно ИЛИ

[Arahnid]

Цитата:

Сообщение от lev

а, ещё нюанс
в БД (Oracle, SQL) массивные поля храняться в виде нескольких полей в виде Dimension, Dimension2_, Dimension3_ ... Dimension25_
а вы в запрос вставляете Dimension[25] база не знает такого поля

Итак попробывала, не помогло

[Arahnid]

Цитата:

Сообщение от miklenew

И ещё интересно как система будет работать с 25 полями.
25 не перебор ли?

Но точно также работает Табель учета рабочего времени (31 день) и все хорошо. Точно также работают Time в зарплате и тоже все хорошо

[Arahnid]

Цитата:

Сообщение от miklenew

У вас длина не умещается в отведённые типом Range 250 символов.
Или скоко там у вас стоит.
Если бы этот query использовался токо в коде проблем бы не было.
Но он у вас идёт на форму, а там есть такое ограничение.

если бы не влезало в 250 символов , то он бы выдал ошибку. А он модчит и не фильтрует.

[Arahnid]

Посмотрела трассировку запроса. Там вооще нет критериев выбора

WHERE (DATAAREAID=?) и все

[Gustav]

Вроде, к массивовым полям нельзя применять синтаксис расширенных диапазонов: http://www.axaptapedia.com/Expressio...es#Limitations

Цитата:

Unfortunately, if you wish to filter on array fields in an Axapta table, such as the Dimensions field, there is no way to do so using the Query Expressions syntax.

Ну, т.е. можно отфильтроваться только по первому - без индекса - и всё на этом...

[Arahnid]

Вот последнего предложения я и не прочла. Значит надо все переделывать. Т.к. дургого решения не вижу.

[Gustav]

Цитата:

Сообщение от Arahnid

Вот последнего предложения я и не прочла. Значит надо все переделывать. Т.к. дургого решения не вижу.

Либо превратите FilmCode в 25 отдельных полей, либо выполните все условия по очереди, без расширенных диапазонов, наберите RecId в Set и потом через запятую вставьте значения из Set'а в range.

P.S. Ну, т.е. не по очереди конечно, а в обычный while select вставьте эти условия и запишите RecId циклом в Set. По окончании в Set'е окажутся только уникальные значения RecId. Их - в range через запятую. Если надо будет показывать запрос пользователю, то возможно еще придется делиться на несколько range по не более 250 символов в каждом.

[Arahnid]

А где можно посмотреть пример такого кода?

[Gustav]

Деления? Например, у меня здесь: Пользовательский генератор строк-перечислений...- 2: Доп.вкладка для SysQueryForm

P.S. Еще вот такую "статику" у себя отыскал:

// Created on 01 Сен 2008 at 15:04:08 by KKU
static Set choppedQueryRanges(  Set _conditions = new Set(Types::String),
                                str _separator  = '||' )
{
    // "Нашинкованные диапазоны критериев"

    // на входе - множество условий (каждая строка существенно короче EDT Range)
    // на выходе - множество диапазонов (каждый максимально впихнут в длину EDT Range)
    // примеры элементов множества условий (_conditions):
    // (CenterId=="09000") или (RequestTable.ReasonId=="ВЫБ_Ф")

    Set             setRanges = new Set(Types::String);
    SetEnumerator   enumerator;
    str             curr;
    str             currElem;
    str             currCrit = '';
    str             prevCrit = '';
    int             edtRangeSize =
                        new DictField( tableNum(TmpSysQuery),
                        fieldNum(TmpSysQuery, RangeValue) ).stringLen();
    ;

    enumerator = _conditions.getEnumerator();
    while (enumerator.moveNext())
    {
        curr = enumerator.current();
        currElem = strLTrim( strRTrim (strFmt(curr)));
        if (currElem)
        {
            currCrit = prevCrit + currElem + _separator;

            if ( strLen(currCrit) > (edtRangeSize + strLen(_separator)) )
            {
                setRanges.add( subStr(prevCrit, 1, strLen(prevCrit)-strLen(_separator)) );
                prevCrit = currElem + _separator;
            }
            else
            {
                prevCrit = currCrit;
            }
        }
    }

    if (prevCrit)
    {
        setRanges.add( subStr(prevCrit, 1, strLen(prevCrit)-strLen(_separator)) );
    }

    return setRanges;
}

Каждый элемент выходного Set - содержимое одной клеточки range. Этот метод в принципе то же самое, что в генераторе содержится в методе doProcessButton, только заточено уже под автономное использование.

[miklenew]

Цитата:

Сообщение от Arahnid

Вот последнего предложения я и не прочла. Значит надо все переделывать. Т.к. дургого решения не вижу.

Если будете переделывать структуру данных, возмите за основу не Dimension, а таблицу InventDim.
Где то давно обсуждалось что при большом количестве Dimension запросы к бд становятся долгими, и это механизм теряет свои плюсы.

[Arahnid]

Спасибо за помощь, много нового узнала.
Решила сделать отдельные поля, т.к. по логике вещей поля равнозначны и вдальнейшем мне придется часто делать подобные выборки.

Еще раз спасибо.