Программное создание заказа на покупку

[niksen]

День добрый!

Пытаюсь программно создать строку заказа, как и сам заказ. Столкнулся с проблемой, что строки заказа не создаются.

Вот код:

static void NewPurch(Args _args)
{
    PurchTable _pTable;
    PurchLine _pLine;
    str _purchId, _PurchName, _OrderAccount, _InvoiceAccount,
    _payment, _vendGroup, _paymentSched, _itemBuyerGroup;

    PurchStatus _purchStatus;
    PurchaseType _PurchaseType;
    SettlementType _SettleVoucher;
    Date _DeliveryDate;

    ;

    _purchId = '00000223_106';
    _PurchName = 'ООО форд';
    _OrderAccount = '000223_053';
    _InvoiceAccount = '000223_053';
    _DeliveryDate = today()+1;
    _payment = '25е число';
    _vendGroup = 'поставщики';
    _paymentSched = 'оплата за месяц';
    _itemBuyerGroup = '1';

    _purchStatus = PurchStatus::Backorder ;
    _PurchaseType = PurchaseType::Journal ;
    _SettleVoucher = SettlementType::None ;

    ttsbegin;

    select forupdate _pTable;
    _pTable.initValue();
    _pTable.PurchId = _purchId;
    _pTable.PurchName = _purchName;
    _pTable.OrderAccount = _OrderAccount;
    _pTable.InvoiceAccount = _InvoiceAccount;
    _pTable.DeliveryDate = _DeliveryDate;
    _pTable.Payment = _payment;
    _pTable.VendGroup = _vendGroup;
    _pTable.PaymentSched = _paymentSched;
    _pTable.ItemBuyerGroupId = _itemBuyerGroup;
    _pTable.PurchStatus = _purchStatus;
    _pTable.PurchaseType = _purchaseType;
    _ptable.SettleVoucher = _SettleVoucher;
    _pTable.CurrencyCode = 'руб';
    _pTable.LanguageId = 'ru';

    _pTable.insert() ;
    
     ttscommit;

 }

это для заказа и вот для строчек заказа

static void NewPurchLine(Args _args)
{
    PurchLine _pLine;

    str _purchId, _ItemId, _purchUnit;
    real _QtyOrdered, _RemainPurchPhysical, _purchPrice,
        _purchQty, _RemainInventPhysical;
    PurchStatus _purchStatus;
    PurchaseType _PurchaseType;
    Date _DeliveryDate;
    ;

    _purchId = '00000223_106';
    _itemId = '001';
    _purchStatus = PurchStatus::Backorder ;
    _DeliveryDate = today()+1;
    _QtyOrdered = 999;
    _RemainPurchPhysical = 999;
    _PurchPrice = 10;
    _PurchUnit = 'шт';
    _PurchQty = 999;
    _PurchaseType = PurchaseType::Journal ;
    _RemainInventPhysical = 999;
    

    ttsbegin;

    select forupdate _pLine;
    _pLine.initValue();
    _pLine.PurchId = _purchId;
    _pLine.ItemId = _itemId;
    _pLine.PurchStatus = _purchStatus;
    _pLine.DeliveryDate = _DeliveryDate;
    _pLine.QtyOrdered = _QtyOrdered;
    _pLine.RemainPurchPhysical = _RemainPurchPhysical;
    _pLine.PurchPrice = _PurchPrice;
    _pLine.PurchUnit = _PurchUnit;
    _pLine.PurchQty = _purchQty;
    _pLine.PurchaseType = _PurchaseType;
    _pLine.RemainInventPhysical = _RemainInventPhysical;


    
    _pLine.insert() ;

    ttscommit;

 }

Вылетает с ошибкой "Код номенклатуры не может быть изменен, если уже созданы складские проводки. Обновление отменено."

Вроде все связи в таблицах посмотрел и всё равно не пойму, где ошибся...

[ice]

ошибок у вас очень много, чтоб их исправить смотрите примеры в самой аксапте.
скажу про одну, чтобы создать новую строку ее не нужно выбирать

[AndyD]

не надо вот это вызывать

 select forupdate _pLine;

сделайте просто

_pLine = null;

у вас подтягивается часть данных из какой-то существующей строки закупки

[ice]

чтобы узнать как создаются строки или заполняются те или иные поля в таблице, попробуйте создать ее через интерфейс, и пробегитесь дебагером по коду

[Ivanhoe]

А еще есть простой способ получить рабочий код для вставки записи в таблицу - в паспорте записи по кнопке "Сценарий" система в буфер вставляет код, который можно прямо в джоб вставить (для инсертов, например, можно транзакцию и не открывать).

[Vals]

А какими бизнес-требованиями вызвано программное создание заказа на покупку?

[niksen]

Ivanhoe
Спасибо, не знал об этом, всё галопом по европам и торопясь и побыстрее, что особо времени не было читать никаких умных книг, я туда только ради вопросов непонятных залезаю, но наверное такими темпами надо будет прочитать парочку от корки до корки и сделать много заданий для закрепления.

Vals
Требование простое - программный периодический перенос из одной системы в другую, т.к. начальству в некоторых смыслах нравится Dynamics AX больше других систем. Кстати, хорошие тренинги у Вас.

ice
Дебаггером я итак пробегаюсь всегда, даже если код работает, чтобы узнать возможные причины. А вот такую простую причину, как блокировка всей таблицы в результате select forupdate я забыл

[jonny]

Лучше стараться по-максимуму пользоваться стандартным API.
Изучите классы PurchAutoCreate*

[niksen]

jonny
PurchAutoCreare - это конечно хорошо, но записи нужно ещё и обновлять иногда. Для этого как ни крути, всё равно программно придётся создавать. Да и не для всех есть AutoCreate. Но в целом, согласен, спасибо, надо использовать

[jonny]

Ну во всяком случае эти классы позволяют разобраться что к чему. К тому же можно создать наследника с нужной вам функциональностью.

[niksen]

jonny
наследники с нужной функциональностью - это конечно хорошо, но есть ли такие почти у каждой таблицы и формы? Как работать с этими классами? Например, ту же запись через PurchAutoCreate через job как создать?

[jonny]

PurchAutoCreate - базовый класс, в функционале аксапты используются его наследники - например PurchAutoCreate_tmpPurchLine.
В случае с ним надо заполнить таблицу tmpPurchLine, подать ее на вход метода construct и вызвать метод create. Пример использования - в классе PurchCreateReleaseOrder.
В вашем случае для задач интеграции можно создать наследника, который бы использовал не временную табличку, а читал бы данные из файла.
Я к чему веду - никто конечно не обязывает вас использовать имеющиеся классы, я привел их для того чтобы вы могли изучить как правильно создавать заказы на покупку, по возможности по-максимуму используя имеющуюся функциональность.
Я думаю преимущества такого подхода несомненны.

[Vals]

Цитата:

Требование простое - программный периодический перенос из одной системы в другую, т.к. начальству в некоторых смыслах нравится Dynamics AX больше других систем.

В аксапте есть Сводное планирование, которое создаёт закупки. А простой перенос из другой системы выглядит не самым лучшим решением (если в ней нет планирования).

[niksen]

Vals
именно для планирования и была выбрана аксапта. Этого нет нигде в таких масштабах и настройках, да при такой цене

[someOne]

У меня работает что то типа такого в Ax2009...

static void createPurch()
{
    AxPurchTable            axPurchTable;
    VendTable               vendTable;
    PurchTable              purchTable;
    AxPurchLine             axPurchLine;
    ;

    vendTable = VendTable::find("тра та та");

    purchTable.initFromVendTable(vendTable);

    axPurchTable = new axPurchTable();
    axPurchTable.PurchTable(purchTable);
    axPurchTable.parmPurchaseType(PurchaseType::Purch);
    axPurchTable.parmInventLocationId("Sklad");
    axPurchTable.parmDimension(vendTable.Dimension);
    axPurchTable.save();

    purchTable = axPurchTable.purchTable();

    info(strfmt("Создана закупка %1 на поставщика %2 с кодом %3", purchTable.PurchId, vendTable.Name, vendTable.AccountNum));
    
            axPurchLine = new axPurchLine();

            axPurchLine.parmPurchId(purchTable.PurchId);
            axPurchLine.parmItemId("ItemId");
            axPurchLine.parmPurchQty(123);
            axPurchLine.parmLineAmount(12);
            axPurchLine.parmLineNum(1);

            axPurchLine.save();

В Ax 3.0 почти все так же, только, если помнится, методы там назывались без указания "parm"