Как заменить "\" на "\\" в пути

[ruslan_as]

есть таблица ProdDataExchangeWithMes_KBK
в которой поле Customers содержит путь типа "C:\Ax\File"
При открытии/записи файла путь должен быть "C\\Ax\\File"
Как заменить "\" на "\\"

Вот код:

Io fileIo = null;
str rec;
ProdDataExchangeWithMes_KBK prodDataExchangeWithMes;
;



prodDataExchangeWithMes=ProdDataExchangeWithMes_KBK::find();
new FileIOPermission(prodDataExchangeWithMes.Customers,@"W").assert();
fileIo=new TextIo(prodDataExchangeWithMes.Customers, @"W", 1251);

rec = "1;2;3;4;5;";
fileIo.write(rec); \\Здесь ругается - Ошибка времени выполнения Io Объект не инициализирован

Подставляю путь C\\Ax\\File - все работает

[db]

\Classes\SysTreeNode\duplicatePathDelimiters

может где и еще есть в более подходящих по смыслу местах

[kornix]

Используйте класс AsciiIo:

void AsciiIoExample()
{
    AsciiIo asciiIo;
    container con;
    FileIoPermission perm;
 
    #define.ExampleFile(@"c:\test.txt")
    #define.ExampleOpenMode("r")
 
    ;
    
    // The AsciiIO.new method runs under code access permission.
    perm = new FileIoPermission(#ExampleFile, #ExampleOpenMode);
    if (perm == null)
    {
        return;
    }
 
    // Code access permission scope starts here.
     perm.assert();
 
    // BP deviation documented.
     asciiIo = new AsciiIo(#ExampleFile, #ExampleOpenMode);
    if (asciiIo != null)
    {
          con = asciiIo.read();
    }
    // Closes the code access permission scope.
    CodeAccessPermission::revertAssert();
}

[ruslan_as]

Премного благодарен - Буду разбираться.

[ruslan_as]

>>kornix
asciiIo.write(rec); - Объект AsciiIo не инициализирован.
В чем ошибка?
Вот код:

AsciiIo asciiIo;
    str rec;


    #define.ExampleFile(@"c:\test.txt")
    #define.ExampleOpenMode("w")

    ;


    perm = new FileIoPermission(#ExampleFile, #ExampleOpenMode);
    if (perm == null)
    {
        return;
    }
     perm.assert();

     asciiIo = new AsciiIo(#ExampleFile, #ExampleOpenMode);
     rec    = "1;2;3;4;5;";
     asciiIo.write(rec);

[kornix]

ruslan_as, попробуйте запустить такой job:

static void Job1(Args _args)
{
    AsciiIo             asciiIo;
    str                 rec;
    FileIoPermission    perm;

    #define.ExampleFile(@"c:\test.txt")
    #define.ExampleOpenMode("w")

    ;


    perm = new FileIoPermission(#ExampleFile, #ExampleOpenMode);
    if (perm == null)
    {
        return;
    }
     perm.assert();

     asciiIo = new AsciiIo(#ExampleFile, #ExampleOpenMode);
     rec    = "1;2;3;4;5;";
     asciiIo.write(rec);

}

Наверно у вас не создан файл C:\test.txt? Если файла не существует, класс asciiIo не инициализируется

[ruslan_as]

>>kornix
Job отработал. Спасибо!
Файла небыло, но он создался.
А вот этот же код в моем проэкте действительно без файла не работает.
А мне файлы надо изначально создавать.
ЧТО ДЕЛАТЬ?

[ruslan_as]

Все решили:

void TXTFile()
{
#define.ExampleOpenMode("w")
Io fileIo = null;
str path;
str rec;
FileIoPermission    perm;
ProdDataExchangeWithMes_KBK prodDataExchangeWithMes;


;

 prodDataExchangeWithMes=ProdDataExchangeWithMes_KBK::find();
 path = SysTreeNode::duplicatePathDelimiters(prodDataExchangeWithMes.Customers+'\\test.txt');

 perm = new FileIoPermission(path, #ExampleOpenMode);
  if (perm == null)
  {
        return;
  }

perm.assert();
fileIo = new TextIo(path, #ExampleOpenMode);
     rec    = "1;2;3;4;5;";
     fileIo.write(rec);
}

[lev]

Цитата:

Сообщение от ruslan_as

Как заменить "\" на "\\"

отвечаю на вопрос

FilePath    filePath = @"C:\test.txt";
    ;

    filePath    = Global::strReplace(filePath, '\\', @'\\');

    info(filePath);

[mazzy]

Цитата:

Сообщение от lev

отвечаю на вопрос

FilePath    filePath = @"C:\test.txt";
    ;

    filePath    = Global::strReplace(filePath, '\\', '\\' + '\\');

    info(filePath);

не, не стоит вводить дополнительную операцию в куче ('\\' + '\\')
Аксапта не такая умная, чтобы вычислить подобное на этапе компиляции.
В результате будет задействована куча и сборка мусора.

Иногда сложение строк в цикле делают просто чтобы код оформить красиво.
В общем, ребяты - не злоупотребляйте сложением строк.
лучше уж использовать четыре слеша или способ написания строки с @

FilePath    filePath = @"C:\test.txt";
    ;

    filePath    = Global::strReplace(filePath, @'\', @'\\');

    info(filePath);

[lev]

добавлю немного к своему примеру

если вдруг вам заранее не известно сколько в тексте слэшов, то можно добавить проверку:

if (!strScan(filePath, @'\\', 1, strLen(filePath)))

т.е. в итоге код будет выглядеть так:

FilePath    filePath = @"C:\test.txt";
    ;

    if (!strScan(filePath, @'\\', 1, strLen(filePath)))
        filePath    = Global::strReplace(filePath, @'\', @'\\');

    info(filePath);

[lev]

Цитата:

Сообщение от mazzy

не, не стоит вводить дополнительную операцию в куче ('\\' + '\\')
Аксапта не такая умная, чтобы вычислить подобное на этапе компиляции.
В результате будет задействована куча и сборка мусора.

Иногда сложение строк в цикле делают просто чтобы код оформить красиво.
В общем, ребяты - не злоупотребляйте сложением строк.
лучше уж использовать четыре слеша или способ написания строки с @

FilePath    filePath = @"C:\test.txt";
    ;

    filePath    = Global::strReplace(filePath, @'\', @'\\');

    info(filePath);

уже исправил себя сам не люблю сложение строк