Проблема с запросом

[Borsugg]

Добрый всем день!

Написал запрос:

    select ForceNestedLoop sum(qty)
        from _inventtrans
        group by Itemid, InventDimId
        where _inventtrans.StatusReceipt == StatusReceipt::Ordered
    exists join _inventsum
        where _inventsum.ItemId == _inventtrans.ItemId
           && _inventsum.inventDimId == _inventtrans.InventDimId
           && _inventsum.Ordered != _inventtrans.Qty;

С помощью запроса хочу получить строки, в которых сумма по InventTrans.Ordered отличается от значения InventSum.Ordered.

Запрос не отрабатывает как надо. Куда копать? Спасибо.

[ice]

зачем?

[pitersky]

я так полагаю, что в момент построения запроса _inventtrans.Qty ещё просто не посчитано. отсюда и проблема.
сделайте селект без сравнения количества, а потом сравнивайте отобранное

[ice]

если вам нужно найти расхождения между inventsum и inventtrans, то есть для этих целей класс inventSumReCalcItem

[S.Kuskov]

Цитата:

Сообщение от Borsugg

Запрос не отрабатывает как надо. Куда копать? Спасибо.

Специфика SQL в аксапте такова, что сначала всегда выполняются все джойны, а только потом группировки. HAVING в аксапте тоже отсутствует. Поэтому единственная возможность здалать такую выбоорку через аксапту - это разбить ваш запрос на два вложенных.

while select ForceNestedLoop sum(qty)
        from _inventtrans
        group by Itemid, InventDimId
        where _inventtrans.StatusReceipt == StatusReceipt::Ordered
{
    select firstonly Ordered from _inventsum
        where _inventsum.ItemId == _inventtrans.ItemId
           && _inventsum.inventDimId == _inventtrans.InventDimId;
    if(_inventsum.Ordered != _inventtrans.qty)
        info(_inventtrans.ItemId)
}

[Borsugg]

Цитата:

Сообщение от S.Kuskov

Специфика SQL в аксапте такова, что сначала всегда выполняются все джойны, а только потом группировки. HAVING в аксапте тоже отсутствует. Поэтому единственная возможность здалать такую выбоорку через аксапту - это разбить ваш запрос на два вложенных.

Как раз думал об этом, что без разбиения не обойтись.. Про специфику спасибо, буду дальше читать мануалы..

Цитата:

Сообщение от ice

если вам нужно найти расхождения между inventsum и inventtrans, то есть для этих целей класс inventSumReCalcItem

Спасибо, обязательно попробую - скорее всего это то, что мне нужно.

Цитата:

Сообщение от pitersky

я так полагаю, что в момент построения запроса _inventtrans.Qty ещё просто не посчитано. отсюда и проблема.
сделайте селект без сравнения количества, а потом сравнивайте отобранное

А

ForceNestedLoop

в этом случае это никак не помогает?

[S.Kuskov]

Цитата:

Сообщение от Borsugg

А

ForceNestedLoop

в этом случае это никак не помогает?

Это же хинт. Хинт который меняет способ выполненя джойна в запросе (но не сам запрос).
Хинты никогда не влияют на результирующую выборку - они влияют на способ её получения.
SQL в Аксапте

[pedrozzz]

Цитата:

Сообщение от S.Kuskov

HAVING в аксапте тоже отсутствует. Поэтому единственная возможность здалать такую выбоорку через аксапту - это разбить ваш запрос на два вложенных.

В 2012 having появился, правда доступен только через объект Query. Небольшой пример, выводит название групп клиентов, в которых меньше 10 участников:

static void QueryHavingExample(Args _args)
{
    Query                   query;
    QueryBuildDataSource    qbds;
    QueryHavingFilter       havingFilter;
    QueryRun                queryRun;
    CustTable               custTable;
    
    query        = new Query();
    qbds         = query.addDataSource(tableNum(CustTable));
    qbds.addGroupByField(fieldNum(CustTable, CustGroup));
    
    havingFilter = query.addHavingFilter(qbds, fieldStr(CustTable, RecId), AggregateFunction::Count);
    havingFilter.value('< 10');
    
    queryRun     = new QueryRun(query);
    
    while (queryRun.next())
    {
        custTable = queryRun.get(tableNum(CustTable));
        
        info(custTable.CustGroup);
    }
    
    info("done");
}