Перебор всех таблиц, имеющих поле определенного типа

[AKIS-Falcon]

Буду весьма благодарен за советы, а также за ссылки на советы на этом форуме или любом другом ресурсе, о том как решить следующую задачу:

Нужно организовать перебор всех таблиц в АОТ, имеющих поле определенного расширенного типа. Для таблиц с таким полем, нужно перебирать все записи, имеющие определенное значение, и изменять это значение на другое.

Аксапта 3.0 SP2, если это имеет значение.

Еще раз заранее спасибо за советы.

[Vadik]

Что касается поиска - несколько способов было здесь

Список полей таблиц на базе конкретного EDT

изменить можно например так:

PHP код:

static void Job2(Args _args)
{
    DictTable       dt;
    DictField       df;
    str             newvalue = "new'name";
    str             oldvalue = "old'name";
    str             execstr;
    XppCompiler     xppCompiler = new XppCompiler();
    ;

    dt = new DictTable(tablenum(LedgerTable));
    df = new DictField(tablenum(LedgerTable), fieldnum(LedgerTable, AccountName));

    execstr =  strfmt('void updatejob() {%1 t; update_recordset t setting %2 = "%3" where t.%4 == "%5";}',
        dt.name(),
        df.name(),
        newvalue,
        df.name(),
        oldvalue);

    info (execstr);

    if (xppCompiler.compile(execstr))
    {
        info ("ok");
        runbuf(execstr);
    }
    else
        error ("error");
} 


Правда, надо еще как минимум поаккуратнее работать с нестроковыми типами, но это уже мелочи

[AKIS-Falcon]

Vadik, спасибо большое!!!!

[mazzy]

Цитата:

Изначально опубликовано AKIS-Falcon
Нужно организовать перебор всех таблиц в АОТ, имеющих поле определенного расширенного типа.

Думаю, стоит рыть в сторону перекрестных ссылок.
http://axapta.mazzy.ru/hints/xref/#040

Стоит встать в АОТ на EDT и спросить чем этот EDT используется.
Отфильтровать записи, которые содержат \Data Dictionary\Tables\

[AKIS-Falcon]

Вот мой вариант того, что в результате получилось - фактически скрестил два Вадиковских куска кода, спасибо ему кстати еще раз

PHP код:

static void ChangeDimension5(Args _args)
{
    Dictionary          dictionary = new Dictionary();
    DictTable           dictTable;
    DictField           dictField;
    DictType            dictType;
    int                 i, j;
    int table_id, field_id, type_id;
    str             execstr;
    XppCompiler     xppCompiler = new XppCompiler();

    extendedTypeId parentTypeId(extendedTypeId _typeId)
    {
        DictType            parentType = new DictType(_typeId);
        ExtendedTypeId      parentId;
        ;

        while (parentType)
        {
            parentId = parentType.id();
            parentType = new DictType(parentType.extend());
        }

        return parentId;
    }

    ;

    for (i = 1; i <= dictionary.tableCnt(); i++)
    {
        dictTable = new DictTable(dictionary.tableCnt2Id(i));

        if (!dictTable.isTmp() && !dictTable.isSystemTable() && !dictTable.isView() && ! dicttable.isMap())
        {
            for (j = 1; j <= dictTable.fieldCnt(); j++)
            {

                dictField = new DictField(dictTable.id(), dictTable.fieldCnt2Id(j));
                if (!dictField.isSystem())
                {
                    if (dictField.baseType() == Types::String)
                    {
                        //if (parentTypeId(dictField.id()) == extendedtypenum(Num))

                        dictType = new DictType(dictField.typeId());
                        type_id = dictfield.typeId();
                        if (!dictType)
                            warning (strfmt("%1.%2 - No Type for the Field", dictTable.name(), dictField.name()));
                       else
                           if(dictField.typeId() == typeid(Dimension) || dictField.typeId() == 132) // Dimension
                           {
                             infolog.add(Exception::Info, strfmt("%1, %2, %3, %4, %5", dictTable.name(), DictField.name(), dicttype.name(), dictfield.typeid(), typeid(Dimension)));
                             execstr =  strfmt('void updatejob() {%1 t; ttsbegin; while select forupdate t  where t.%4[5] like "%5" { t.%2[5] = "%3"; t.update(); } ttscommit;}',
                             dicttable.name(),
                             dictfield.name(),
                             '10',
                             dictfield.name(),
                             '*');

                             info (execstr);

                             if (xppCompiler.compile(execstr))
                             {
                              info ("ok");
                              runbuf(execstr);
                             }
                             else
                              error ("error");
                           }

                    }
                }
            }
        }
    }
} 


Комментарии:
1. Как видно, тип у меня текстовый, так что никаких доппроверок не делаю
2. Не стал заморачиваться с длинным наследованием типа "внук-правнук" и пр. Ограничился только прямым
3. Немного поменял сам код, изменяющий значения полей - update record_setting почему-то не пошло...

Вот.

[AKIS-Falcon]

Добавлю, что такие массовые обновления вообще-то надо вести очень осторожно. К примеру, может оказаться, что новое значение делает запись в таблице неуникальной по первичному ключу -> она не может быть сохранена -> выполнение всей процедуры прерывается. Т.е. неплохо бы обрабатывать такие ситуации по try.. catch. Насколько я понимаю, могут также быть затруднения и похуже...

[George Nordic]

На всякий случай напомню о функции RemanePrimaryKey.

С Уважением,
Георгий.

[AKIS-Falcon]

Спасибо за напоминание

Было дело, пользовался ею - когда план счетов меняли.

[wb]

Цитата:

Изначально опубликовано George Nordic
На всякий случай напомню о функции RemanePrimaryKey.

можите сказать что имеется ввиду?

я сделал немного по другому:

на форме Dimensions метод источника Dimensions

PHP код:

public void write()
{
    SysDim  oldValueSysDim = Dimensions.orig().Num;
    ;
    super();
    InventUpdateDimension_ew::run(Dimensions.DimensionCode, oldValueSysDim, Dimensions.Num);
} 


метод класса InventUpdateDimension_ew

PHP код:

// w 11.02.2005 Axapta 3.0 CIS SP1
public static void run(DimensionCode _dimCode, SysDim _oldSysDim, SysDim _newSysDim)
{
    Dictionary  dictionary = new Dictionary();
    DictTable   dictTable;
    DictField   dictField;
    int         i, j;

    #define.FieldId_Dimension(132)

    void update(TableId _tableId, FieldId _fieldId)
    {
        Query                   q = new Query();
        QueryBuildDataSource    qbds;
        QueryRun                qr;
        Common                  common;
        FieldId                 fieldId_Dimension = fieldId2ext(_fieldId, _dimCode + 1);

        ;
        qbds = q.addDataSource(_tableId);
        qbds.update(true);
        qbds.addRange(fieldId_Dimension).value(strfmt('\"%1\"', _oldSysDim));
        qr = new QueryRun(q);
        while (qr.next())
        {
            common = qr.getNo(1);
            common.(fieldId_Dimension) = _newSysDim;
            common.doUpdate();
        }
    }

    ;
    ttsbegin;
    for (i = 1; i <= dictionary.tableCnt(); i++)
    {
        dictTable = new DictTable(dictionary.tableCnt2Id(i));
        if (!dictTable.isTmp() && !dictTable.isSystemTable() && !dictTable.isView() && !dictTable.isMap())
        {
            for (j = 1; j <= dictTable.fieldCnt(); j++)
            {
                dictField = new DictField(dictTable.id(), dictTable.fieldCnt2Id(j));
                if (!dictField.isSystem() && dictField.typeId() == #FieldId_Dimension)
                    update(dictTable.id(), dictField.id());
            }
        }
    }
    ttscommit;
    info(strfmt('Проведена замена аналитики %1 на %2', _oldSysDim, _newSysDim));
} 


С уважением,
wb